C***************************************************************C
      SUBROUTINE ALKATO(PTE, PCF, KNCF, PRC, KERMSG)
C***************************************************************C
C*    EXCITATION RATE COEFFICIENTS BY KATO (TYPE = 1)          *C
C*            +    +    +    +    +    +    +    +             *C
C*        PTE    : ELECTRON TEMPERATURE (EV)                   *C
C*        PRC    : RATE COEFFICIENT (CM[3]/SEC)                *C
C*        KERMSG : ERROR MESSAGE                               *C
C*            +    +    +    +    +    +    +    +             *C
C*        PCF(1)         =  EIJ : THRESHOLD ENERGY             *C
C*        PCF(2)         =  GI  : STATISTICAL WEIGHT           *C
C*        PCF(3)-(7)     =  A-E : COEFFICIENTS OF FITTING      *C
C*        PCF(8)-(10)    =  P,Q,X1 : RESONANCE                 *C
C*            +    +    +    +    +    +    +    +             *C
C*                                     BY T. KATO              *C
C*            +    +    +    +    +    +    +    +             *C
C*        MODIFIED FROM SUBROUTINE RATEN                       *C
C*            OCT.11, 1990             BY K. TAKASUGI          *C
C***************************************************************C
C--- EXCITATION RATE COEFFICIENT FROM IPPJ-AM-27 -------
c     SUBROUTINE RATE27(TEMP,EIJ,GI,ITYPE,A,B,C,D,E,F,CRATE)
C
      IMPLICIT REAL*8 (A-H,O-Z)
      DIMENSION PCF(10)
      CHARACTER*(*) KERMSG
C
        KERMSG=' '
        S=0.5
        CONST=8.010E-8/(SQRT(PTE)*PCF(2))
        Y=PCF(1)/PTE
C
      if(PCF(1).gt.0.0) then
        RA=PCF(3)/Y + PCF(5) + S*PCF(6)*(1.-Y)
        RB=PCF(4) - PCF(5)*Y + S*PCF(6)*Y*Y + PCF(7)/Y
        PRC=CONST*EXP(-Y)*Y*(RA+EIEXP(Y)*RB)
      else
        tl=log10(PTE*11600)
        rc=PCF(3)+(PCF(4)+(PCF(5)+PCF(6)/tl)/tl)/tl
        PRC=CONST*EXP(-Y)*10.0**rc
      endif
C
      if(KNCF .gt. 7) then
        RRES=CONST*EXP(-Y)
     &      *(PCF(8)*(1.+1./Y)*(1.-EXP((1.-PCF(10))*Y)
     &        *(PCF(10)+1./Y)/(1.+1./Y))
     &      + PCF(9)*(1.-EXP((1.-PCF(10))*Y)))
        PRC=PRC + RRES
      endif
C
      RETURN
      END
C